Патч Amulet Tel Fyr // Мини-Мод Морровинд

[Kor.Angar]

Амулет Тель Фира - фикс

magasScript

Begin magasScript

if ( OnDeath == 1 )
    MessageBox "Вы победили лорда Дрегаса Волара. Даэдрический амулет, который принес вас в это место, исчезает из вашего снаряжения."
    ;Player->PositionCell, 3996.000, 3920.000, 14408.000, 180, "Tower of Tel Fyr, Hall of Fyr"
    ;Player->AddItem "daedric_crescent_unique" 1
    Player->RemoveItem "Daedric_special" 1
endif

End magasScript

amuletTelFyrScript

Begin AmuletTelFyrScript

short button
short OnPcEquip
short PCSkipEquip
short stepbystep
; messageOn reset и doOnce неиспользуется. оставил что бы не было вылетов на старом сейве
short messageOn
short reset
short doOnce

set PCSkipEquip to 1

if ( OnPCEquip == 1 )
    set stepbystep to 1
    Set OnPCEquip to 0  
endif 

if ( stepbystep == 0)
    return
endif

if ( stepbystep == 1)
        if ( player->GetPCRank "Telvanni" >= 9 )
            ;Магистр
            MessageBox "Teleport to" "Cancel" "Tel Fyr" "Tel Vos" "Tel Uvirith" "Tel Aruhn" "Tel Branora" "Tel Mora" "Tel Naga"
        elseif ( player->GetPCRank "Telvanni" >= 7 )
            ;Волшебник
            MessageBox "Teleport to" "Cancel" "Tel Fyr" "Tel Vos" "Tel Uvirith"
        elseif ( player->GetPCRank "Telvanni" >= 5 )
            ;Говоряший
            MessageBox "Teleport to" "Cancel" "Tel Fyr" "Tel Vos"
        else
            MessageBox "Teleport to" "Cancel" "Tel Fyr"
        endif     
        set stepbystep to 2
endif 


; меню с вариантами создано -> мониторим
if ( stepbystep == 2)

        set button to GetButtonPressed

        if ( button >= 0 )
            ; кнопка была нажата, отключаем мониторинг
            set stepbystep to 3
        endif
endif    

; нажата кнопка телепорта
if ( stepbystep == 3)
        
    Set stepbystep to 0
 
    ;получить координаты места через консоль
    ;player -> getpos, x
    ;player -> getpos, y
    ;player -> getpos, z
    
    if ( button > 0 )
        ; герой куда то полетел
        PlaySound, "mysticism hit"
        
        If ( MenuMode == 1 )
            ;меню открыто -> закрываем 
            MenuTest
        endif
    Endif
    
    if ( button == 0 )
        ; нажата кнопка "отмена"
        PlaySound, "spellmake fail"
    elseif ( button == 1 )      
            ;Tel Fyr
            Player->PositionCell, 4168, 4732, 14902, 0, "Tower of Tel Fyr, Hall of Fyr"
    elseif ( button == 2 )
            ;Tel Vos
            Player->PositionCell, 3817,3158,15742, 0, "tel vos, aryon's chambers"
    elseif ( button == 3 )
            ;Tel Uvirith
            Player->PositionCell, 759, -600, 1026, 0, "Tel Uvirith, Tower Upper"
    elseif ( button == 4 )
            ;Tel Aruhn
            Player->PositionCell, 274,-756, 71, 0, "Tel Aruhn, Upper Tower"
    elseif ( button == 5 )
            ;Tel Branora
            Player->PositionCell, -190, 1508, -714, 0, "Tel Branora, Upper Tower: Therana's Chamber"
    elseif ( button == 6 )
            ;Tel Mora
            Player->PositionCell, -475, -439, 980, 0, "Tel Mora, Upper Tower"
    elseif ( button == 7 )
            ;Tel Naga
            Player->PositionCell, 265, 965, 1026, 0, "Sadrith Mora, Tel Naga Upper Tower"
    else
            ;какая то ошибка --> полетили в Тел Фир
            Player->PositionCell, 4168, 4732, 14902, 0, "Tower of Tel Fyr, Hall of Fyr"
    endif
    ; добавить телепорт в Гнисис??   

        
endif  


End    AmuletTelFyrScript

 

[Kor.Angar]

обновил: теперь если герой состоит в Доме Телванни, амулет будет телепортировать героя и в его собственную Башню расположенную на кладбище. А если герой возглавит дом Телванни, то сможет телепортироваться в любую башню дома Телванни.